XtGem tutorial

First the script creates a cookie containing a non-repeating random sequence between 1 and the total number of files in the folder
The last number is a check value of the number of files in the folder so that if you add more files the cookie will reset
although it may take some time for the cache to refresh and include the new images

When the page loads the first number in the cookie is read and then placed at the end (before the check value) and the cookie is refreshed

NOTE
if the folder is very large the script may time out while creating the random sequence I tested the bare script with up to 1100 entries
but the limit may be about 500 for the full script depending on if you have any other xtscripts running on the page

Xtscript

# settings
var $path=/my_images
var $filter=*.*
var $user=YOUR XTCAT USERNAME
var $key=YOUR XTCAT KEY
var $stars = 5
var $interval=Day
var $text1=Total Average Rating 
var $text2=Not Yet Rated. Be The First. 
var $text3=Your Rating 
var $text4=Out Of 
var $text5=Total Votes 
var $button1= Rate It!  
var $cookie_name = rndimg
var $cookie_expire = 2419200

# script
var $list=<xt:filelist sort_type="name" sort_dir="asc" folder="$path" template="|.file_name." per_page="" filter="$filter"/>|
var $number=<xt:filelist sort_type="name" sort_dir="asc" folder="$path" template="*" per_page="" filter="$filter"/>
var $number=call strlen $val=$number
var $cookie=call cookie::get $name=$cookie_name;$default=0
if $cookie
goto @loop3
endif
@loop1
var $cookie=call mt_rand $min=1;$max=$number
var $cookie=.$cookie.
var $count=1
@loop2
var $rand=call mt_rand $min=1;$max=$number
var $used=call strpos $haystack=.$cookie;$needle=.$rand.
if  $used 
goto @loop2
endif
var $cookie=$cookie$rand.
var $count=($count+1)
if $count < $number
goto @loop2
endif
var $cookie=$cookie$number
call cookie::set $name=$cookie_name; $val=$cookie;$expire=$cookie_expire;$force_current=1
@loop3
var $check_start=call strrpos $haystack=$cookie;$needle=.;
var $check=call substr $val=$cookie;$start=($check_start+1);
if not $check==$number
call cookie::set $name=$cookie_name; $val=0;$expire=-1;$force_current=1
goto @loop1
endif
var $num_end= call strpos $haystack=$cookie;$needle=.;$offset=1
var $num=call substr $val=$cookie;$start=1;$length=($num_end-1)
var $length= call strrpos $haystack=$cookie;$needle=.;
var $cookie=call substr $val=$cookie;$start=$num_end;$length=($length-$num_end+1)
var $cookie=$cookie$num.$number
call cookie::set $name=$cookie_name; $val=$cookie;$expire=$cookie_expire;$force_current=1
var $offset=1
var $entry_count=1
@loop4
var $entry_end= call strpos $haystack=$list;$needle=|;$offset=$offset
if $entry_count < $num
var $entry_count=($entry_count+1)
var $offset=($entry_end+1)
goto @loop4
endif
var $entry=call substr $val=$list;$start=$offset;$length=($entry_end-$offset)
var $call=call crc32 $val=$key$entry

# output
var $template=.file_name_base_parsed. <br /><img style='max-width:100%' src='.file_url.' alt='.file_name.' /><br /><xt:widget tool="Ratings" interval="$interval" call="$call" key="$key" xtuser="$user" stars="$stars" text1="$text1" text2="$text2" text3="$text3" text4="$text4" text5="$text5" button1="$button1" id="xt.c.a.t." />
var $template=call htmlspecialchars $val=$template
var $output=<xt:filelist  folder="$path" template="$template"  filter="$entry"/>
print <div style="text-align:center;margin:1em 0">$output</div>

tbackground